mirror of
git://git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
synced 2025-08-05 16:54:27 +00:00
a32e93e100
Move the contents of arch/sparc/lib/crypto/ into lib/crypto/sparc/. The new code organization makes a lot more sense for how this code actually works and is developed. In particular, it makes it possible to build each algorithm as a single module, with better inlining and dead code elimination. For a more detailed explanation, see the patchset which did this for the CRC library code: https://lore.kernel.org/r/20250607200454.73587-1-ebiggers@kernel.org/. Also see the patchset which did this for SHA-512: https://lore.kernel.org/linux-crypto/20250616014019.415791-1-ebiggers@kernel.org/ This is just a preparatory commit, which does the move to get the files into their new location but keeps them building the same way as before. Later commits will make the actual improvements to the way the arch-optimized code is integrated for each algorithm. Acked-by: Ard Biesheuvel <ardb@kernel.org> Reviewed-by: Martin K. Petersen <martin.petersen@oracle.com> Reviewed-by: Sohil Mehta <sohil.mehta@intel.com> Link: https://lore.kernel.org/r/20250619191908.134235-8-ebiggers@kernel.org Signed-off-by: Eric Biggers <ebiggers@kernel.org>
78 lines
1.5 KiB
ArmAsm
78 lines
1.5 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
#include <linux/linkage.h>
|
|
#include <asm/opcodes.h>
|
|
#include <asm/visasm.h>
|
|
|
|
ENTRY(sha256_sparc64_transform)
|
|
/* %o0 = state, %o1 = data, %o2 = nblocks */
|
|
VISEntryHalf
|
|
ld [%o0 + 0x00], %f0
|
|
ld [%o0 + 0x04], %f1
|
|
ld [%o0 + 0x08], %f2
|
|
ld [%o0 + 0x0c], %f3
|
|
ld [%o0 + 0x10], %f4
|
|
ld [%o0 + 0x14], %f5
|
|
andcc %o1, 0x7, %g0
|
|
ld [%o0 + 0x18], %f6
|
|
bne,pn %xcc, 10f
|
|
ld [%o0 + 0x1c], %f7
|
|
|
|
1:
|
|
ldd [%o1 + 0x00], %f8
|
|
ldd [%o1 + 0x08], %f10
|
|
ldd [%o1 + 0x10], %f12
|
|
ldd [%o1 + 0x18], %f14
|
|
ldd [%o1 + 0x20], %f16
|
|
ldd [%o1 + 0x28], %f18
|
|
ldd [%o1 + 0x30], %f20
|
|
ldd [%o1 + 0x38], %f22
|
|
|
|
SHA256
|
|
|
|
subcc %o2, 1, %o2
|
|
bne,pt %xcc, 1b
|
|
add %o1, 0x40, %o1
|
|
|
|
5:
|
|
st %f0, [%o0 + 0x00]
|
|
st %f1, [%o0 + 0x04]
|
|
st %f2, [%o0 + 0x08]
|
|
st %f3, [%o0 + 0x0c]
|
|
st %f4, [%o0 + 0x10]
|
|
st %f5, [%o0 + 0x14]
|
|
st %f6, [%o0 + 0x18]
|
|
st %f7, [%o0 + 0x1c]
|
|
retl
|
|
VISExitHalf
|
|
10:
|
|
alignaddr %o1, %g0, %o1
|
|
|
|
ldd [%o1 + 0x00], %f10
|
|
1:
|
|
ldd [%o1 + 0x08], %f12
|
|
ldd [%o1 + 0x10], %f14
|
|
ldd [%o1 + 0x18], %f16
|
|
ldd [%o1 + 0x20], %f18
|
|
ldd [%o1 + 0x28], %f20
|
|
ldd [%o1 + 0x30], %f22
|
|
ldd [%o1 + 0x38], %f24
|
|
ldd [%o1 + 0x40], %f26
|
|
|
|
faligndata %f10, %f12, %f8
|
|
faligndata %f12, %f14, %f10
|
|
faligndata %f14, %f16, %f12
|
|
faligndata %f16, %f18, %f14
|
|
faligndata %f18, %f20, %f16
|
|
faligndata %f20, %f22, %f18
|
|
faligndata %f22, %f24, %f20
|
|
faligndata %f24, %f26, %f22
|
|
|
|
SHA256
|
|
|
|
subcc %o2, 1, %o2
|
|
fsrc2 %f26, %f10
|
|
bne,pt %xcc, 1b
|
|
add %o1, 0x40, %o1
|
|
|
|
ba,a,pt %xcc, 5b
|
|
ENDPROC(sha256_sparc64_transform)
|